I've never used the Table of Contents capabilities of Word (for shame!). I'd asked about using info in the footers for the following publication: a collection of one-page teacher projects which are organized by focus area (printed in the footer). I wanted the TOC to print the focus area and the page number where an area first appears, since there are no chapter/intro pages. Last year I finally figured out what was happening with section breaks, SAME AS PREVIOUS, and footers...and now it's mine! Is there a way to get what I want with TOC?

Hi, Rosemary!

So glad you saw that correction -- thanks for coming to the site.

Workarounds for what you want to do are going to be quite cumbersome -- and, I felt bad for misdirecting you in the first place :) -- so I wrote you a little macro that should do the trick. You'll just have to do a tiny bit of set up and then be good to go. This post is really long because it gives you a lot of instructions. I posted the code for the macro at the end of this comment, but don't worry -- you don't need to know a thing about VBA (macro) code to use it. If you dont know how to get it into Word or get started using it, let me know and I'll post steps for setting it up.

SOME INSTRUCTIONS\DETAIL ABOUT THIS MACRO:

This macro will add a Table of Contents wherever your insertion point is ... the TOC will be created only from text in the footer that is styled in a particular style (so it doesn't take other footer text you don't want). For my macro, I told Word to look for footer text that uses the Heading 1 paragraph style - but you can replace this with any style name you choose, as long as the style exists in a document where you want to use the macro to create a TOC. Otherwise, you'll get an error when you use the macro.

Also - I assumed that you were not using the Different First Page or different Odd\Even headers and footers in these documents. It will take correctly-styled text from any footer, so if you are using those footer types -- make sure you don't get unwanted extra TOC entries. Also, it's set up for a single-level table of contents (it uses Word's built-in table of contents style TOC 1, but you can change that as well).

The macro is set up to tab from the footer text to the page number on each line of the TOC, so you'll want to add the "TOC 1" style to your document and format it to include a right-aligned page number (with a tab leader if you like), so that the formatting of the created TOC looks right. All documents come with the TOC styles available, but you won't see access to it by default from the Styles & Formatting task pane. Let me know if you need help getting that done, and I'll post a sample.

HERE IS THE MACRO (Again ... don't worry if you don't know how to read macros -- you don't have to... I can help you get it set up. Just let me know if you need help)

Sub footerTOC()

Dim aft As HeaderFooter
Dim asc As Section
Dim apr As Paragraph
Dim counter As Integer
counter = 0

On Error GoTo ErrorHandler
For Each asc In ActiveDocument.Sections
For Each aft In asc.Footers
For Each apr In aft.Range.Paragraphs
If apr.Style = "Heading 1" Then
counter = counter + 1
With Selection
.Style = "TOC 1"
.TypeText (apr.Range.Text)
.TypeBackspace
.TypeText (vbTab & apr.Range.Information(wdActiveEndAdjustedPageNumber) & vbCr)
End With
End If
Next apr
Next aft
Next asc

If counter = 0 Then
MsgBox "Your document contains no footer text in the style required for creating a TOC with this macro.", vbInformation
End If

Exit Sub

ErrorHandler:
MsgBox "This TOC macro ended in error. Check to ensure that the required style exists in the document and then retry."

End Sub

[END SUB, above, was the end of the macro code]

Hope this helps!

Best,
Stephanie